[ESP32]セマフォを使用する方法(xSemaphore) with Arduino IDE

TaskHandle_t thp[2];
SemaphoreHandle_t xSemaphore;

// the setup function runs once when you press reset or power the board
void setup() {
  
  // initialize serial communication at 115200 bits per second:
  Serial.begin(115200);
  
  // セマフォ作成
  xSemaphore = xSemaphoreCreateBinary();
  if(xSemaphore == NULL) 
  {
    Serial.println("セマフォ取得失敗");
  }
  else
  {
    xSemaphoreGive( xSemaphore );
  }

  // Now set up two tasks to run independently.
  xTaskCreatePinnedToCore( TaskA, "TaskA", 2048, NULL, 2, &thp[0], APP_CPU_NUM);
  xTaskCreatePinnedToCore( TaskB, "TaskB", 2048, NULL, 2, &thp[1], APP_CPU_NUM);
}

void loop()
{
  // Empty. Things are done in Tasks.
}

/*--------------------------------------------------*/
/*---------------------- Tasks ---------------------*/
/*--------------------------------------------------*/
void TaskA(void *pvParameters)  // This is a task.
{
  Serial.println("TaskA Start");
  while( 1 ) {
    // セマフォ取得
    if( xSemaphoreTake( xSemaphore, 0 ) == pdTRUE )
    {
      Serial.println("TaskA セマフォ取得成功");
      delay(5000);
      // セマフォ解放
      xSemaphoreGive( xSemaphore );
      delay(2000);
    }
    else
    {
      Serial.println("TaskA セマフォ取得待ち");
      delay(1000);
    }
  }
  // ここにはこないが明示的にタスク終了を記載しておく。
  vTaskDelete(NULL);
}

void TaskB(void *pvParameters)  // This is a task.
{
  Serial.println("TaskB Start");
  while( 1 ) {
    // セマフォ取得
    if( xSemaphoreTake( xSemaphore, 0 ) == pdTRUE )
    {
      Serial.println("TaskB セマフォ取得成功");
      delay(5000);
      // セマフォ解放
      xSemaphoreGive( xSemaphore );
      delay(2000);
    }
    else
    {
      Serial.println("TaskB セマフォ取得待ち");
      delay(1000);
    }
  }
  // ここにはこないが明示的にタスク終了を記載しておく。
  vTaskDelete(NULL);
}